plugins {
  id 'base'
}

/* 
 * Project version must be duplicated in the add-ons table-of-contents file (*.toc).
 * No template manager or annotation parser is used for this purpose.
 * That way, a ToC file with a placeholder for version that remains
 * unprocessed will never be packaged and distributed.
 */
version = '1.0.0wip'

tasks.create('ldoc', Exec) {
  executable 'ldoc'
  args "--dir=${projectDir}/doc/", "${projectDir}/src/"
}

tasks.create('luacheck', Exec) {
  executable 'luacheck'
  args "--config .luacheckrc", "${projectDir}/src/"
}

/*
 * The game client imposes a restriction on the add-on directory name.
 * Specifically, only letters are allowed and no numbers or special characters.
 * Therefore, version number is not included in the packaged add-on directory's name.
 * However, the version number is still included in the distributed archive name.
 */
tasks.create('distZip', Zip) {
  from("$projectDir") {
    include '.luacheckrc'
    include 'README.md'
    include 'build.gradle'
    include "${project.name}.toc"

    into("${project.name}")
  }

  from("$projectDir/src/") {
    into("${project.name}/src/")
    include '**/*.lua'
  }

  from("$projectDir/doc/") {
    into("${project.name}/doc/")
  }

  from("$projectDir/resources/") {
    into("${project.name}/resources/")
  }
}

distZip.dependsOn(ldoc)
check.dependsOn(luacheck)
assemble.dependsOn(distZip)